body common control
{
      inputs => {
        "../default.cf.sub",
        "./prepare_files_for_simulate_tests.cf.sub",
        "./normalize_agent_output.cf.sub"
      };
      bundlesequence  => { default("$(this.promise_filename)") };
      version => "1.0";
}


bundle agent init
{
  methods:
    "prepare_files_for_simulate_tests";
}

bundle agent test
{
  meta:
    "test_soft_fail" string => "(solaris|aix|hpux|windows)",
      meta => { "ENT-6540,ENT-10254" };
      # ENT-6540 exotics fail to delete chroot
      # ENT-10254 tests fail on Windows due to CRLF

    "description" -> { "ENT-5301" }
      string => "Test that files promises in --simulate=manifest-full mode produce proper output and only make changes in chroot";

  commands:
    # add --verbose here and look at the .actual log for debugging sub policy runs
    "$(sys.cf_agent) -Kf $(this.promise_dirname)$(const.dirsep)promises.cf.sub --simulate=manifest-full > $(this.promise_filename).temp 2>&1"
      contain => in_shell,
      comment => "Run sub policy in manifest mode and capture output to $(this.promise_filename).actual file.";
}

bundle agent check
{
  methods:
    "normalize_agent_results" usebundle => normalize_agent_results("$(this.promise_filename).temp",
                                                                   "$(this.promise_filename).actual");
    "check" usebundle => dcs_check_diff("$(this.promise_filename).actual",
                                        "$(this.promise_filename).expected",
                                        "$(this.promise_filename)");
}
