#######################################################
# Test that classes are set on individual installation (Mantis #829)
#######################################################

body common control
{
      inputs => { "../default.sub.cf" };
      bundlesequence => { default("$(this.promise_filename)") };
      version => "1.0";
}

bundle agent init
{
  vars:
      "dummy" string => "dummy";
}

bundle agent test
{
  packages:
      "a:b:c"
      package_policy => "add",
      package_method => mock,
      if => "!a",
      classes => ok("a");

      "d:e:f"
      package_policy => "add",
      package_method => mock,
      if => "!d",
      classes => ok("d");
}

body package_method mock
{
      package_changes => "individual";
      package_list_command => "$(G.true)";

      package_list_name_regex => "^[^:]*";
      package_list_version_regex => ":(?<=:).*(?=:)";
      package_list_arch_regex => "[^:]\w+$";
      package_installed_regex => "^[^:]*";

      package_add_command => "$(G.true)";
      package_update_command => "$(G.true)";
      package_delete_command => "$(G.true)";
      package_verify_command => "$(G.true)";
}

body classes ok(classname)
{
      promise_repaired => { "$(classname)" };
      promise_kept => { "$(classname)" };
}

bundle agent check
{
  reports:
    a.d::
      "$(this.promise_filename) Pass";
    !a|!d::
      "$(this.promise_filename) FAIL";
}
### PROJECT_ID: core
### CATEGORY_ID: 29
