bundle common test_meta
{
  vars:
    "description" string => "A user present gets the hashed password changed";
    "story_id" string => "5525";
    "covers" string => "operational_repaired";
}

#######################################################
body common control
{
  inputs => { "../../default.sub.cf", "user_queries.cf.sub" };
  bundlesequence => { default("$(this.promise_filename)") };
}

#######################################################
bundle common hpux_trusted
{
  classes:
    "hpux_trusted_mode_test"
      expression => regcmp(".*hpux_trusted.*", $(this.promise_filename));
}

bundle agent init
{
  meta:
    "test_skip_unsupported" string => "hpux_trusted_mode_test.!hpux";

  users:
    "johndoe"
      policy => "present",
      password => init_password;
}

body password init_password
{
  format => "plaintext";
  data => "Bad0P4SSW0RD";
}

#######################################################
bundle agent test
{
  vars:
    "hash" string => "dTloMVpjYt1w2";

  users:
    "johndoe"
      policy => "present",
      password => test_password;
}

body password test_password
{
  format => "hash";
  data => "$(test.hash)";
}

#######################################################
bundle agent check
{
  methods:
    !windows::
      "any"
        usebundle => user_has_password_hash(
          "johndoe", "$(test.hash)", "success", "failure"
        ),
        classes => always("methods_run");

    windows::
      # Hash not supported on Windows. Make sure it is the same as before.
      "any"
        usebundle => user_has_password(
          "johndoe", "Bad0P4SSW0RD", "success", "failure"
        ),
        classes => always("methods_run");

  classes:
    "ready" expression => "methods_run";
    "ok" and => { "success", "!failure" };

  reports:
    ok.ready::
      "$(this.promise_filename) Pass";

    !ok.ready::
      "$(this.promise_filename) FAIL";
}
